!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
! Main driver of plotting and uv analysis procedures
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
let verify sic%verify /new logical
sic verify off
!
! Enable last procedure or task to be called again when go is called alone.
!
if ("&1none".eq."none") then
   if (command.eq." ") then
      let command /prompt "Please give a PROCEDURE or TASK name: " /lower
   endif
else
   let command "&1" /lower
endif
!
! Execute presumed command.
!
define character fich*80 ext*6
let fich macro#dir:p_'command'
if (file("'fich'.greg")) then
  @ p_'command'.greg &2 &3 &4 &5 &6 &7 &8 &9
  ext = "greg"
else if (file("'fich'.map")) then
  @ p_'command'.map &2 &3 &4 &5 &6 &7 &8 &9
  ext = "map"
else if (file("'fich'.class")) then
  @ p_'command'.class &2 &3 &4 &5 &6 &7 &8 &9
  ext = "class"
else if (file("task#dir:'command'.exe")) then
  on error continue
  if (sic%window) then
    vector\run 'command'
  else
    vector\run 'command' /edit
  endif
  on error
else
   say " "
   say 'bold'" No PROCEDURE or TASK named "'command''norm'
   say " Type ""input ?"" to get the list of available commands"
   say " "
endif
!
let fich macro#dir:s_'command'.'ext'
if (file(fich)) then
  @ s_'command'.'ext'
endif
!
! Restore Verify mode to previous status
!
if verify then
  sic verify on
endif
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
