!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
if .not.exist(qckimg%exist) then
  define structure qckimg% /global
  define logical qckimg%exist qckimg%useopt /glob
  define character qckimg%name*132 /glob
  define character qckimg%scal*4 /glob
  define real qckimg%min qckimg%max /glob
  let qckimg%scal lin
endif
!
gui\panel "Quick Display of an Image" gag_pro:x_quickdisplayimage.hlp
let qckimg%name 'qckimg%name' /prompt "File name " /file "*.gdf"
say "Optional Parameters"
let qckimg%useopt 'qckimg%useopt' /prompt "Use Optional Parameters"
let qckimg%scal 'qckimg%scal' /prompt "Scaling mode" /choice lin log equ
let qckimg%min 'qckimg%min' /prompt "Low Cut"
let qckimg%max 'qckimg%max' /prompt "High Cut"
!
gui\button "@ p_quickdisplayimage.greg" "Display Current Image"
gui\button "vector\header 'qckimg%name'" "Show Current Header"
on error return
gui\go "@ p_quickdisplayimage.greg"
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
