!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
begin procedure linedb-cache
  linedb\use in &1
  linedb\use out my&1.db /over
  linedb\select /freq 80000 120000
  linedb\insert
  linedb\select /freq 126000 175000
  linedb\insert
  linedb\select /freq 200000 275000
  linedb\insert
end procedure linedb-cache
!
begin procedure linedb-insert
  if ("&1".eq."jpl") then
     linedb\use in jpl
  else
     linedb\use in "my&1.db"
  endif
  linedb\select /freq  80000 120000 /species "&2" /energy 100
  linedb\insert
  linedb\select /freq 126000 175000 /species "&2" /energy 100
  linedb\insert
  linedb\select /freq 200000 275000 /species "&2" /energy 100
  linedb\insert
end procedure linedb-insert
!
begin procedure linedb-build-private
  linedb\use out hydrocarbons.db /over
  !
  @ linedb-insert cdms "CCH, v=0"
  @ linedb-insert cdms "C-13-CH"
  @ linedb-insert cdms "CC-13-H"
  !
  @ linedb-insert cdms "l-C3H2"
  @ linedb-insert cdms "c-C3H2"
  !
  @ linedb-insert jpl "c-C3H"
  @ linedb-insert cdms "C3H, v4=0,1mS"
  @ linedb-insert cdms "C4H, v=0"
  !
end procedure linedb-build-private
!
begin procedure linedb-list-private
  linedb\use in hydrocarbons.db
  linedb\select /freq 80000 100000 /energy 30
  linedb\list
  pause
  linedb\select /species "C3H, v4=0,1mS" /energy 30
  linedb\list
  exa lines%
  exa lines%species
  exa lines%eup
end procedure linedb-list-private
!
begin procedure linedb-remove
  linedb\use both hydrocarbons.db
  linedb\select /freq  80000 120000 /species "&1"
  linedb\list
  pause
  linedb\remove
  linedb\list
end procedure linedb-remove
!
begin procedure linedb-from-personal-catalog
  sic copy gag_demo:demo-53001.cat demo-53001.cat
  sic copy gag_demo:partfunc.json partfunc.json
  sic copy gag_demo:partfunc.cat partfunc.cat 
  !
  linedb\use in  demo-53001.cat
  linedb\use out demo-53001.db /over
  linedb\select
  linedb\list
  pause
  linedb\insert
  linedb\use in demo-53001.db
  linedb\select
  linedb\list
end procedure linedb-from-personal-catalog
!
begin procedure linedb-clean
  sic delete mycdms.db
  sic delete hydrocarbons.db
  sic delete demo-53001.cat
  sic delete demo-53001.db
  sic delete partfunc.cat
  sic delete partfunc.json
end procedure linedb-clean
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
@ linedb-cache cdms
@ linedb-build-private
@ linedb-list-private
@ linedb-remove "l-C3H2"
@ linedb-from-personal-catalog
@ linedb-clean
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
